home *** CD-ROM | disk | FTP | other *** search
/ Programmer Power Tools / Programmer Power Tools.iso / dirutl / tree.arc / TREE.ASM next >
Assembly Source File  |  1986-08-27  |  14KB  |  535 lines
  1. ; tree.asm    g.r.green
  2. ; program to draw directory tree of the default drive 
  3. ; running msdos.
  4. ; 
  5. ; changes made to accomodate for the IBM line drawing set 
  6. ; Hans ZURFCC::Zangger Aug 86 {Baum == german for 'tree'
  7. ;
  8. ;        TREE.ASM Copyright (C) by Gordon R. Green
  9. ;               9-May-1985 All Rights Reserved. Released For Any
  10. ;               use without cost exceeding the cost of handling
  11. ;               and reproduction, as long this heading is
  12. ;               included with all or any part used of this
  13. ;               program and credit given to Gordon R. Green.
  14. ;
  15. ;                Gordon R. Green
  16. ;            7 Juniper St.
  17. ;            Hudson, N.H. 03051
  18. ;
  19. ;
  20. ; Installation Instructions:
  21. ;    masm tree
  22. ;    link tree        ; ignore lack of stack err msg!!!
  23. ;    exe2bin tree.exe tree.com
  24. ;    del tree.exe
  25. ;
  26. ; Invocation:
  27. ;    TREE            ; takes no arguments
  28.  
  29.  
  30. ;**************************************************************
  31. ; Macro definitions
  32.  
  33. ;    DISPLAY STRING
  34. display    macro    string
  35.     mov    dx,offset string
  36.     mov    ah,9
  37.     int    doscall
  38.     endm
  39.  
  40. ;    SET_DTA
  41. set_dta    macro    buffer
  42.     mov    dx,offset buffer
  43.     mov    ah,1AH
  44.     int    doscall
  45.     endm
  46.  
  47. ;    SEARCH_FIRST
  48. search_first    macro    fcb
  49.     mov    dx,offset fcb
  50.     mov    ah,11H
  51.     int    doscall
  52.     endm
  53. ;
  54. FSCROLL     EQU    6        ;BIOS function = scroll
  55. FLOCATE     EQU    2        ;BIOS function = locate
  56. COLOR        EQU    7        ;attribute, white on black background
  57. ALL        EQU    0        ;indicates entire screen on scroll
  58. HOR             EQU     196
  59. VER             EQU     179
  60. COR             EQU     192
  61. LFIN            EQU     195
  62. TFIN            EQU     194
  63. BFIN            EQU     192
  64. FACE            EQU     1
  65. ;
  66. BIOSCAL MACRO    FUNCTION
  67.     MOV    AH,FUNCTION             ;specify function desired
  68.     INT    10H                     ;call BIOS for desired function
  69. ENDM
  70. ;
  71.  
  72. SCROLL    MACRO    POS1,POS2,ATTRIBUTE,ROWS
  73. ;;coordinates to be presented in row,col format as a single number, as:
  74. ;;row * 256 + col
  75. ;;
  76. ;;POS1      =upper left coordinate
  77. ;;POS2      =lower right coordinate
  78. ;;ATTRIBUTE =color descriptor of fill character
  79. ;;ROWS      =how many rows to be scrolled (0=do entire screen)
  80.                                         
  81.     MOV    CX,POS1                 ;upper left corner
  82.     MOV    DX,POS2                 ;botton right corner
  83.     MOV    BH,ATTRIBUTE            ;pass how to color fill
  84.     MOV    AL,ROWS                 ;do entire window
  85.     BIOSCAL FSCROLL                 ;request scroll function from bios
  86. ENDM
  87. ;
  88. LOCATE    MACRO    ROW,COL
  89.     MOV    DH,ROW                  ;move cursor to this row
  90.     MOV    DL,COL                  ;and to this col in this screen number
  91.     MOV    BH,0
  92.     BIOSCAL FLOCATE                 ;move cursor
  93. ENDM
  94. ;
  95. ; End of macros
  96. ;**************************************************************
  97.  
  98.  
  99. ;**************************
  100. ;***            ***
  101. ;***    EQU Statements    ***
  102. ;***            ***
  103. ;**************************
  104.  
  105. max_level    equ    14
  106. doscall        equ    21H
  107.  
  108. ; dos calls
  109. type_chr    equ    2
  110. find_file    equ    4EH
  111. find_nxt_file    equ    4FH
  112.  
  113. ; ASCII characters
  114. CR        equ    0DH
  115. LF        equ    0AH
  116. H_TAB        equ    9
  117.  
  118.  
  119. ;**************************
  120. ;***            ***
  121. ;***    Main Program    ***
  122. ;***            ***
  123. ;**************************
  124.  
  125. ;***********************************************************
  126. prognam    segment    ;define code segment
  127.  
  128.     org    100H
  129.  
  130.     assume cs:prognam, ds:prognam, ss:prognam
  131.  
  132. start:
  133.     push    ds            ; set up return to DOS
  134.     call    crlf
  135.     xor    ax,ax            ; clear ax
  136.     push    ax
  137.     call    init            ; init tables, save current directory,
  138.                     ;   switch to root
  139. ; read disk name and display it
  140.  
  141.     set_dta    buffer
  142.     search_first    fcb        ; look for disk name
  143.     cmp    al,0FFH            ; found?
  144.     jne    name_fnd        ; if yes
  145. ;       mov     al," "                  ; else fill in blank name
  146. ;display hig_vid
  147. display no_label                        ; else say No Label
  148. jmp nolabel
  149.         mov     di,offset buffer+8
  150.     mov    cx,11
  151.     repz    stosb
  152. name_fnd:
  153.     mov    al,"$"            ; insert string terminator
  154.     mov    buffer[19],al
  155. ;display hig_vid
  156. ;display spaces1
  157.         display buffer[8]               ; display name in reverse video
  158. nolabel:
  159. ;display reg_vid
  160.     display    link            ; draw lines down to main tree
  161.     mov    unused,3        ; force proper positioning later
  162.  
  163. ; read root directory into memory and sort it
  164.     mov    di,offset buf        ; pntr to filename storage
  165.     mov    begin_dir,di
  166.     call    get_file_names        ; get filenames for this level
  167.     mov    bx,level
  168.     mov    begin_dir[bx+2],di    ; mark start of next level
  169.     mov    num_dir[bx],ax        ; save # of directories at this level
  170.     cmp    ax,0            ; any sub-diretories?
  171.         je      no_sub_dirs             ;   if none in root, then no tree
  172.  
  173. main_loop:
  174.     mov    bx,level        ; all dirs done at this level?
  175.     mov    ax,cur_dir[bx]
  176.     cmp    ax,num_dir[bx]
  177.     jne    more_dirs        ; if not
  178.     cmp    bx,0            ; are we at top level?
  179.     jne    up            ; if no
  180. abort:  jmp     quit                    ; if yes
  181. more_dirs:
  182.     call    dn_level        ; go down one level
  183.     mov    bx,level        ; init di with where to store filenames
  184.     mov    di,begin_dir[bx]
  185.     call    get_file_names
  186.     mov    bx,level        ; save pntr for next level
  187.     mov    begin_dir[bx+2],di
  188.     mov    num_dir[bx],ax        ; save # dirs at this level
  189.     mov    cur_dir[bx],0        ; set cur_dir=0 for this level
  190.     cmp    ax,0            ; any dirs?
  191.     jne    more_dirs        ; if yes, go dn another level
  192.     call    crlf
  193.     mov    unused,-1
  194. up:
  195.     call    up_level        ; else go up a level
  196.     mov    bx,level        ;   bump cnt of cur_dir
  197.     inc    cur_dir[bx]
  198.     jmp    main_loop        ;   and loop back
  199. quit:
  200.     call    crlf
  201.     mov    ah,3BH            ; restore original directory
  202.     mov    dx,offset old_dir
  203.     int    doscall
  204.     ret                ; exit to dos
  205.  
  206. no_sub_dirs:
  207.         display no_subdirs
  208.         jmp quit
  209.  
  210. ;**********************************
  211. ;***                ***
  212. ;***    Support Routines    ***
  213. ;***                ***
  214. ;**********************************
  215.  
  216. ;**************************************************************
  217. ; initialize a bunch of things
  218. ;    on entry ax = 0
  219. init:
  220. ; init tables (begin_dir, num_dir, cur_dir)
  221.     mov    di,offset begin_dir    ; (ax = 0)
  222.     mov    cx,max_level * 3
  223.     repz    stosw
  224.     mov    level,ax        ; (ax = 0)
  225.  
  226. ; init default file spec at 5CH
  227.     mov    al,"?"            ; fill with wildcards
  228.     mov    di,byte ptr 5DH        ;    default fcb+1
  229.     mov    cx,11
  230.     repz    stosb
  231.  
  232. ; save current directory name
  233.     mov    ah,47H            ; get current directory name
  234.     mov    si,offset old_dir+1    ;    and put here
  235.     mov    dl,0            ;    from present drive
  236.     int    doscall
  237.  
  238. ; change to root_directory
  239.     mov    ah,3BH            ; change current directory
  240.     mov    dx,offset root_dir    ;    to root-directory
  241.     int    doscall
  242.         scroll    0,24*256+79,color,all    ; scroll row=24, col=79 (zero relative)
  243.         locate    0,0            ;Cursor to top left at (0,0)
  244.         locate  0,65
  245.     display    sign_on            
  246.         locate  0,0
  247.     ret                ;   escape sequence
  248.  
  249.  
  250. ;**************************************************************
  251. ; move down a directory level
  252.  
  253. dn_level:
  254. ; move to new directory
  255.     mov    bx,level
  256.     mov    si,begin_dir[bx]    ; where names start for this level
  257.     mov    ax,cur_dir[bx]        ; cur_dir
  258.     mov    cx,11
  259.     mul    cl            ; times size = offset
  260.     add    ax,si            ; ax points to next name
  261.     mov    si,ax            ; move to si
  262.     mov    di,offset dn_dir + 2
  263.     mov    cx,8            ; ready to move 8 chars
  264.     repz    movsb
  265.     call    show_name        ; display the directory name
  266.     mov    ah,3BH            ; change current directory
  267.     mov    dx,offset dn_dir
  268.     cmp    level,0
  269.     jne    dn_lv
  270.     inc    dx
  271. dn_lv:
  272.     int    doscall            ;### error chk?
  273.     inc    level            ; adjust level count
  274.     inc    level            ;    by 2
  275.     ret
  276.  
  277.  
  278. ;**************************************************************
  279. ; show directory name
  280.  
  281. show_name:
  282.     cmp    unused,-1        ; new line?
  283.     jne    shnm0            ;   if not
  284.     call    do_indents
  285.     mov    unused,0
  286. shnm0:    mov    cx,unused        ; any unused?
  287.     cmp    cx,0            ;   if not
  288.     je    shnm2
  289. shnm1:  mov     dl, HOR                 ;   else pad with hor lines
  290.     mov    ah,2
  291.     int    doscall
  292.     loop    shnm1
  293. shnm2:    mov    bx,level
  294.         mov     end_pad, LFIN           ; init end_pad to left "T"
  295.         cmp     cur_dir [bx],0          ; determine end_pad value
  296.     jne    shnm3
  297.         mov     end_pad, TFIN           ; if 1st, top "T"
  298. shnm3:  mov     ax,cur_dir [bx]
  299.         inc     ax
  300.         cmp     ax,num_dir [bx]
  301.     jne    shnm4
  302.         mov     end_pad, BFIN            ; if last, lower left corner
  303. shnm4:    dec    ax
  304.     cmp    ax,0
  305.     jne    shnm5
  306.     cmp    num_dir[bx],1
  307.     jg    shnm5
  308.         mov     end_pad, HOR             ; if 1st & last, horizontal line
  309. shnm5:    mov    dl,end_pad        ; output end_pad
  310.     mov    ah,2
  311.     int    doscall
  312. ;display spaces1
  313. ;display hig_vid                 ; switch to reverse video
  314.     mov    bx,offset dn_dir + 2    ; output name
  315.     mov    dl,[bx]            ;   first character
  316.     mov    ah,2
  317.     int    doscall
  318.     inc    bx
  319.     mov    cx,7            ; 7 more characters in filename
  320. shnm6:    mov    dl,[bx]            ; all but first char in lower case
  321.     cmp    dl,0
  322.     je    shnm8            ; if nul
  323.     cmp    dl,"A"
  324.     jl    shnm7
  325.     cmp    dl,"Z"
  326. ;       jg      shnm7
  327. ;       or      dl," "
  328. shnm7:    mov    ah,2            ; finally output char
  329.     int    doscall
  330.     inc    bx
  331.     loop    shnm6            ; loop for all chars
  332. shnm8:    mov    unused,cx
  333. ;display spaces1
  334. ;display reg_vid                 ; back to normal video
  335.     ret
  336.  
  337.  
  338. ;**************************************************************
  339. ; handle the indents at beginning of line
  340.  
  341. do_indents:
  342.         mov     bx,0                    ; "level" for this routine
  343. do_ind1:
  344.     display    spaces8            ; output leading spaces8
  345.     cmp    bx,level        ; done if present level
  346.     je    do_ind3
  347.     mov    dl," "            ;   else output space
  348.         mov     ax,cur_dir [bx]
  349.     inc    ax
  350.         cmp     ax,num_dir [bx]
  351.     je    do_ind2
  352. ;display spaces1
  353.         mov     dl, VER                  ;   or vertical bar
  354. do_ind2:
  355.     mov    ah,2
  356.     int    doscall
  357. do_ind3:
  358.     inc    bx            ; bump local index
  359.     inc    bx
  360.     cmp    bx,level        ; see if we are done
  361.     jle    do_ind1            ;    if not
  362.     ret
  363.  
  364. ;**************************************************************
  365. ; move up a directory level
  366.  
  367. up_level:
  368.     mov    ah,3BH            ; change current directory
  369.     mov    dx,offset up_dir    ;   up a level
  370.     int    doscall            ;### error chk?
  371.     dec    level            ; adjust level count
  372.     dec    level            ;   by 2
  373.     ret
  374.  
  375.  
  376. ;**************************************************************
  377. ; get list of files that match
  378. ;    entry -        di = addr of place to put data
  379. ;    return -    di = addr of next data loc
  380. ;            ax = # files found (stored in tmp_cnt during routine)
  381.  
  382. get_file_names:
  383.     mov    tmp_loc,di
  384.     mov    tmp_cnt,0        ; init file cntr for this routine
  385.     push    di
  386.     set_dta fb_reserve        ; set data transfer area
  387.     mov    al,0            ; clear fb_pname area
  388.     mov    di,offset fb_pname
  389.     mov    cx,11
  390.     repz    stosb
  391.     pop    di
  392.     mov    ah,find_file        ; find match file
  393.     mov    dx,5DH            ; point at default fcb+1
  394.     mov    cx,010H            ; attributes to look for
  395.     int    doscall
  396.     jnc    sav_nam            ; if we found something
  397.     mov    ax,0            ; else
  398.     ret                ;    return with cnt=0
  399.  
  400. sav_nam:
  401.     cmp    fb_attr,10H        ; directory?
  402.     jne    no_save            ;   if not
  403.     cmp    fb_pname, '.'        ; named "."?
  404.     je    no_save            ;   if yes
  405.     mov    si,offset fb_pname    ; else save filename
  406.     mov    cx,11
  407.     repz    movsb
  408.     inc    tmp_cnt            ; bump file cnt
  409. no_save:
  410.     push    di
  411.     mov    al,0            ; clear fb_pname area
  412.     mov    di,offset fb_pname
  413.     mov    cx,13
  414.     repz    stosb
  415.     pop    di
  416.     mov    ah,find_nxt_file    ; find nxt file match
  417.     int    doscall
  418.     cmp    al,18            ; any file?
  419.     jnz    sav_nam            ;    yes
  420.     call    sort
  421.     mov    ax,tmp_cnt        ;    no, return  ax = tmp_cnt
  422.     ret
  423.  
  424.  
  425. ;**************************************************************
  426. ; sort list of files
  427. ;    entry -        di = nxt data loc
  428. ;            tmp_loc = start of data to sort
  429. ;            tmp_cnt = how many to sort
  430. ;    return -    di = nxt data loc
  431. ;            data area is sorted
  432.  
  433. sort:    push    di
  434.         cmp     tmp_cnt,1               ; more than one?
  435.     jnz    sort_start        ;    yes
  436.     jmp    sort_done        ;    no - only one
  437. sort_start:
  438.     mov    bx,tmp_loc
  439.     mov    dl,0
  440.     mov    dh,1
  441. sort1:    mov    si,bx
  442.     mov    di,si
  443.     add    di,11
  444.     mov    cx,8
  445.     repz    cmpsb
  446.     jle    sort3
  447.     mov    cx,11
  448.     mov    dl,1
  449.     mov    si,bx
  450.     mov    di,si
  451.     add    di,11
  452. sort2:    mov    al,[si]
  453.     xchg    [di],al
  454.     mov    [si],al
  455.     inc    si
  456.     inc    di
  457.     loop    sort2
  458. sort3:    add    bx,11
  459.     inc    dh
  460.     mov    al,dh            ;### expand to 16 bit cnt
  461.     xor    ah,ah
  462.     cmp    ax,tmp_cnt
  463.     jl    sort1
  464.     cmp    dl,1
  465.     jz    sort_start
  466. sort_done:
  467.     pop    di
  468.     ret
  469.  
  470. ;**************************************************************
  471. ; type cr, lf
  472. crlf:
  473.     display    crlf_msg
  474.     ret
  475.  
  476. ;**********************************
  477. ;***                ***
  478. ;***    Storage Allocation    ***
  479. ;***                ***
  480. ;**********************************
  481.  
  482. ;**************************************************************
  483. crlf_msg    db    CR, LF, "$"
  484. root_dir    db    "\",0
  485. up_dir          db      "..",0              ; go up a directory level
  486. dn_dir        db    ".\", 16 dup (?)
  487. old_dir         db      "\",  64 dup (?)    ; saves original directory
  488. no_label        db      "No DiskLabel$"
  489. no_subdirs      db      " No SubDirs$"
  490. sign_on         db      "Baum V1.2 ", FACE, "$"
  491. end_pad         db      (?)                 ; graphic joining character
  492. link            db      CR, LF, "    ", COR, "$"; link from disk name
  493. spaces8         db      "        $"         ; 8 spaces
  494. spaces1         db      " $"                ; 1 space
  495. tmp_cnt         dw      (?)                 ; temporary counter
  496. tmp_loc         dw      (?)                 ; tmp location storage
  497. unused          dw      -1                  ; # chars not used in field
  498.  
  499. ; 'level' is current directory level (0 = root), and is used as index into
  500. ; begin_dir, num_dir, and cur_dir arrays.  begin_dir array stores addresses
  501. ; in buf where the data for each level begins.  num_dir array stores the
  502. ; number of directories at each level.  cur_dir array stores the number
  503. ; of the directory being processed at each level.  Whenever we move up
  504. ; one level, the data for all lower levels is obsolete and the pointers
  505. ; are now invalid and the corresponding area in 'buf' may be re-used.
  506.  
  507. level           dw      (?)               ; current level ( 0 - ((n-1)*2) )
  508. begin_dir    dw    max_level dup (?) ; index within BUF where data starts
  509. num_dir        dw    max_level dup (?) ; # dirs at this level
  510. cur_dir        dw    max_level dup (?) ; # of dir being proc. at this level
  511.  
  512. ; CAUTION!!!  be careful when making modifications.
  513. ; The buffers from here on are used at different times and are overlapping.
  514. ; 'fcb' overlaps 'buffer', and 'buffer' overlaps 'fb_*' and 'buf'.
  515.  
  516. fcb    db    0FFH, 0,0,0,0,0,8, 0, "???????????"
  517. buffer        db    (?)
  518.  
  519. fb_reserve    db    21 dup (?)    ; data returned about file
  520. fb_attr        db    ?
  521. fb_time        dw    ?
  522. fb_date        dw    ?
  523. fb_size_lo    dw    ?
  524. fb_size_hi    dw    ?
  525. fb_pname    db    13 dup (?)
  526.  
  527. buf:        db    (?)        ; buffer area from here to stack
  528.                     ; stores sorted directories for
  529.                     ; all levels
  530.  
  531. prognam    ends        ;end of code segment
  532.     end  start    ;end assembly
  533.  
  534.  
  535.